forked from Minki/linux
b24413180f
Many source files in the tree are missing licensing information, which makes it harder for compliance tools to determine the correct license. By default all files without license information are under the default license of the kernel, which is GPL version 2. Update the files which contain no license information with the 'GPL-2.0' SPDX license identifier. The SPDX identifier is a legally binding shorthand, which can be used instead of the full boiler plate text. This patch is based on work done by Thomas Gleixner and Kate Stewart and Philippe Ombredanne. How this work was done: Patches were generated and checked against linux-4.14-rc6 for a subset of the use cases: - file had no licensing information it it. - file was a */uapi/* one with no licensing information in it, - file was a */uapi/* one with existing licensing information, Further patches will be generated in subsequent months to fix up cases where non-standard license headers were used, and references to license had to be inferred by heuristics based on keywords. The analysis to determine which SPDX License Identifier to be applied to a file was done in a spreadsheet of side by side results from of the output of two independent scanners (ScanCode & Windriver) producing SPDX tag:value files created by Philippe Ombredanne. Philippe prepared the base worksheet, and did an initial spot review of a few 1000 files. The 4.13 kernel was the starting point of the analysis with 60,537 files assessed. Kate Stewart did a file by file comparison of the scanner results in the spreadsheet to determine which SPDX license identifier(s) to be applied to the file. She confirmed any determination that was not immediately clear with lawyers working with the Linux Foundation. Criteria used to select files for SPDX license identifier tagging was: - Files considered eligible had to be source code files. - Make and config files were included as candidates if they contained >5 lines of source - File already had some variant of a license header in it (even if <5 lines). All documentation files were explicitly excluded. The following heuristics were used to determine which SPDX license identifiers to apply. - when both scanners couldn't find any license traces, file was considered to have no license information in it, and the top level COPYING file license applied. For non */uapi/* files that summary was: SPDX license identifier # files ---------------------------------------------------|------- GPL-2.0 11139 and resulted in the first patch in this series. If that file was a */uapi/* path one, it was "GPL-2.0 WITH Linux-syscall-note" otherwise it was "GPL-2.0". Results of that was: SPDX license identifier # files ---------------------------------------------------|------- GPL-2.0 WITH Linux-syscall-note 930 and resulted in the second patch in this series. - if a file had some form of licensing information in it, and was one of the */uapi/* ones, it was denoted with the Linux-syscall-note if any GPL family license was found in the file or had no licensing in it (per prior point). Results summary: SPDX license identifier # files ---------------------------------------------------|------ GPL-2.0 WITH Linux-syscall-note 270 GPL-2.0+ WITH Linux-syscall-note 169 ((GPL-2.0 WITH Linux-syscall-note) OR BSD-2-Clause) 21 ((GPL-2.0 WITH Linux-syscall-note) OR BSD-3-Clause) 17 LGPL-2.1+ WITH Linux-syscall-note 15 GPL-1.0+ WITH Linux-syscall-note 14 ((GPL-2.0+ WITH Linux-syscall-note) OR BSD-3-Clause) 5 LGPL-2.0+ WITH Linux-syscall-note 4 LGPL-2.1 WITH Linux-syscall-note 3 ((GPL-2.0 WITH Linux-syscall-note) OR MIT) 3 ((GPL-2.0 WITH Linux-syscall-note) AND MIT) 1 and that resulted in the third patch in this series. - when the two scanners agreed on the detected license(s), that became the concluded license(s). - when there was disagreement between the two scanners (one detected a license but the other didn't, or they both detected different licenses) a manual inspection of the file occurred. - In most cases a manual inspection of the information in the file resulted in a clear resolution of the license that should apply (and which scanner probably needed to revisit its heuristics). - When it was not immediately clear, the license identifier was confirmed with lawyers working with the Linux Foundation. - If there was any question as to the appropriate license identifier, the file was flagged for further research and to be revisited later in time. In total, over 70 hours of logged manual review was done on the spreadsheet to determine the SPDX license identifiers to apply to the source files by Kate, Philippe, Thomas and, in some cases, confirmation by lawyers working with the Linux Foundation. Kate also obtained a third independent scan of the 4.13 code base from FOSSology, and compared selected files where the other two scanners disagreed against that SPDX file, to see if there was new insights. The Windriver scanner is based on an older version of FOSSology in part, so they are related. Thomas did random spot checks in about 500 files from the spreadsheets for the uapi headers and agreed with SPDX license identifier in the files he inspected. For the non-uapi files Thomas did random spot checks in about 15000 files. In initial set of patches against 4.14-rc6, 3 files were found to have copy/paste license identifier errors, and have been fixed to reflect the correct identifier. Additionally Philippe spent 10 hours this week doing a detailed manual inspection and review of the 12,461 patched files from the initial patch version early this week with: - a full scancode scan run, collecting the matched texts, detected license ids and scores - reviewing anything where there was a license detected (about 500+ files) to ensure that the applied SPDX license was correct - reviewing anything where there was no detection but the patch license was not GPL-2.0 WITH Linux-syscall-note to ensure that the applied SPDX license was correct This produced a worksheet with 20 files needing minor correction. This worksheet was then exported into 3 different .csv files for the different types of files to be modified. These .csv files were then reviewed by Greg. Thomas wrote a script to parse the csv files and add the proper SPDX tag to the file, in the format that the file expected. This script was further refined by Greg based on the output to detect more types of files automatically and to distinguish between header and source .c files (which need different comment types.) Finally Greg ran the script using the .csv files to generate the patches. Reviewed-by: Kate Stewart <kstewart@linuxfoundation.org> Reviewed-by: Philippe Ombredanne <pombredanne@nexb.com> Reviewed-by: Thomas Gleixner <tglx@linutronix.de> Signed-off-by: Greg Kroah-Hartman <gregkh@linuxfoundation.org>
102 lines
2.3 KiB
ArmAsm
102 lines
2.3 KiB
ArmAsm
/* SPDX-License-Identifier: GPL-2.0 */
|
|
/*
|
|
* S390 kdump lowlevel functions (new kernel)
|
|
*
|
|
* Copyright IBM Corp. 2011
|
|
* Author(s): Michael Holzheu <holzheu@linux.vnet.ibm.com>
|
|
*/
|
|
|
|
#include <asm/sigp.h>
|
|
|
|
#define DATAMOVER_ADDR 0x4000
|
|
#define COPY_PAGE_ADDR 0x6000
|
|
|
|
#ifdef CONFIG_CRASH_DUMP
|
|
|
|
#
|
|
# kdump entry (new kernel - not yet relocated)
|
|
#
|
|
# Note: This code has to be position independent
|
|
#
|
|
|
|
.align 2
|
|
.Lep_startup_kdump:
|
|
lhi %r1,2 # mode 2 = esame (dump)
|
|
sigp %r1,%r0,SIGP_SET_ARCHITECTURE # Switch to esame mode
|
|
sam64 # Switch to 64 bit addressing
|
|
basr %r13,0
|
|
.Lbase:
|
|
larl %r2,.Lbase_addr # Check, if we have been
|
|
lg %r2,0(%r2) # already relocated:
|
|
clgr %r2,%r13 #
|
|
jne .Lrelocate # No : Start data mover
|
|
lghi %r2,0 # Yes: Start kdump kernel
|
|
brasl %r14,startup_kdump_relocated
|
|
|
|
.Lrelocate:
|
|
larl %r4,startup
|
|
lg %r2,0x418(%r4) # Get kdump base
|
|
lg %r3,0x420(%r4) # Get kdump size
|
|
|
|
larl %r10,.Lcopy_start # Source of data mover
|
|
lghi %r8,DATAMOVER_ADDR # Target of data mover
|
|
mvc 0(256,%r8),0(%r10) # Copy data mover code
|
|
|
|
agr %r8,%r2 # Copy data mover to
|
|
mvc 0(256,%r8),0(%r10) # reserved mem
|
|
|
|
lghi %r14,DATAMOVER_ADDR # Jump to copied data mover
|
|
basr %r14,%r14
|
|
.Lbase_addr:
|
|
.quad .Lbase
|
|
|
|
#
|
|
# kdump data mover code (runs at address DATAMOVER_ADDR)
|
|
#
|
|
# r2: kdump base address
|
|
# r3: kdump size
|
|
#
|
|
.Lcopy_start:
|
|
basr %r13,0 # Base
|
|
0:
|
|
lgr %r11,%r2 # Save kdump base address
|
|
lgr %r12,%r2
|
|
agr %r12,%r3 # Compute kdump end address
|
|
|
|
lghi %r5,0
|
|
lghi %r10,COPY_PAGE_ADDR # Load copy page address
|
|
1:
|
|
mvc 0(256,%r10),0(%r5) # Copy old kernel to tmp
|
|
mvc 0(256,%r5),0(%r11) # Copy new kernel to old
|
|
mvc 0(256,%r11),0(%r10) # Copy tmp to new
|
|
aghi %r11,256
|
|
aghi %r5,256
|
|
clgr %r11,%r12
|
|
jl 1b
|
|
|
|
lg %r14,.Lstartup_kdump-0b(%r13)
|
|
basr %r14,%r14 # Start relocated kernel
|
|
.Lstartup_kdump:
|
|
.long 0x00000000,0x00000000 + startup_kdump_relocated
|
|
.Lcopy_end:
|
|
|
|
#
|
|
# Startup of kdump (relocated new kernel)
|
|
#
|
|
.align 2
|
|
startup_kdump_relocated:
|
|
basr %r13,0
|
|
0: lpswe .Lrestart_psw-0b(%r13) # Start new kernel...
|
|
.align 8
|
|
.Lrestart_psw:
|
|
.quad 0x0000000080000000,0x0000000000000000 + startup
|
|
#else
|
|
.align 2
|
|
.Lep_startup_kdump:
|
|
larl %r13,startup_kdump_crash
|
|
lpswe 0(%r13)
|
|
.align 8
|
|
startup_kdump_crash:
|
|
.quad 0x0002000080000000,0x0000000000000000 + startup_kdump_crash
|
|
#endif /* CONFIG_CRASH_DUMP */
|