4332195c56
Up until now we have always paid attention to make sure the length of the new instruction replacing the old one is at least less or equal to the length of the old instruction. If the new instruction is longer, at the time it replaces the old instruction it will overwrite the beginning of the next instruction in the kernel image and cause your pants to catch fire. So instead of having to pay attention, teach the alternatives framework to pad shorter old instructions with NOPs at buildtime - but only in the case when len(old instruction(s)) < len(new instruction(s)) and add nothing in the >= case. (In that case we do add_nops() when patching). This way the alternatives user shouldn't have to care about instruction sizes and simply use the macros. Add asm ALTERNATIVE* flavor macros too, while at it. Also, we need to save the pad length in a separate struct alt_instr member for NOP optimization and the way to do that reliably is to carry the pad length instead of trying to detect whether we're looking at single-byte NOPs or at pathological instruction offsets like e9 90 90 90 90, for example, which is a valid instruction. Thanks to Michael Matz for the great help with toolchain questions. Signed-off-by: Borislav Petkov <bp@suse.de>
74 lines
1.4 KiB
ArmAsm
74 lines
1.4 KiB
ArmAsm
#include <linux/linkage.h>
|
|
#include <asm/dwarf2.h>
|
|
#include <asm/alternative-asm.h>
|
|
|
|
/*
|
|
* Zero a page.
|
|
* rdi page
|
|
*/
|
|
ENTRY(clear_page_c)
|
|
CFI_STARTPROC
|
|
movl $4096/8,%ecx
|
|
xorl %eax,%eax
|
|
rep stosq
|
|
ret
|
|
CFI_ENDPROC
|
|
ENDPROC(clear_page_c)
|
|
|
|
ENTRY(clear_page_c_e)
|
|
CFI_STARTPROC
|
|
movl $4096,%ecx
|
|
xorl %eax,%eax
|
|
rep stosb
|
|
ret
|
|
CFI_ENDPROC
|
|
ENDPROC(clear_page_c_e)
|
|
|
|
ENTRY(clear_page)
|
|
CFI_STARTPROC
|
|
xorl %eax,%eax
|
|
movl $4096/64,%ecx
|
|
.p2align 4
|
|
.Lloop:
|
|
decl %ecx
|
|
#define PUT(x) movq %rax,x*8(%rdi)
|
|
movq %rax,(%rdi)
|
|
PUT(1)
|
|
PUT(2)
|
|
PUT(3)
|
|
PUT(4)
|
|
PUT(5)
|
|
PUT(6)
|
|
PUT(7)
|
|
leaq 64(%rdi),%rdi
|
|
jnz .Lloop
|
|
nop
|
|
ret
|
|
CFI_ENDPROC
|
|
.Lclear_page_end:
|
|
ENDPROC(clear_page)
|
|
|
|
/*
|
|
* Some CPUs support enhanced REP MOVSB/STOSB instructions.
|
|
* It is recommended to use this when possible.
|
|
* If enhanced REP MOVSB/STOSB is not available, try to use fast string.
|
|
* Otherwise, use original function.
|
|
*
|
|
*/
|
|
|
|
#include <asm/cpufeature.h>
|
|
|
|
.section .altinstr_replacement,"ax"
|
|
1: .byte 0xeb /* jmp <disp8> */
|
|
.byte (clear_page_c - clear_page) - (2f - 1b) /* offset */
|
|
2: .byte 0xeb /* jmp <disp8> */
|
|
.byte (clear_page_c_e - clear_page) - (3f - 2b) /* offset */
|
|
3:
|
|
.previous
|
|
.section .altinstructions,"a"
|
|
altinstruction_entry clear_page,1b,X86_FEATURE_REP_GOOD,\
|
|
.Lclear_page_end-clear_page, 2b-1b, 0
|
|
altinstruction_entry clear_page,2b,X86_FEATURE_ERMS, \
|
|
.Lclear_page_end-clear_page,3b-2b, 0
|
|
.previous
|